lenheart/DNF_DEV
1
0
Fork 0
Code Issues Pull Requests Actions Packages Projects Releases Wiki Activity

建档

Browse Source
This commit is contained in:
Lenheart
2025-10-06 04:18:49 +08:00
commit df2cacdb92
2784 changed files with 1280840 additions and 0 deletions
Download Patch File Download Diff File Expand all files Collapse all files

48
Library/SDL2_image-2.5.2/Xcode/pkg-support/resources/CMake/sdl2_image-config-version.cmake Normal file
View File

@@ -0,0 +1,48 @@
# based on the files generated by CMake's write_basic_package_version_file
# SDL2_image CMake version configuration file:
# This file is meant to be placed in Resources/CMake of a SDL2_image framework
if(NOT EXISTS "${CMAKE_CURRENT_LIST_DIR}/../../Headers/SDL_image.h")
message(AUTHOR_WARNING "Could not find SDL_image.h. This script is meant to be placed in the Resources/CMake directory of SDL2_image.framework")
return()
endif()
file(READ "${CMAKE_CURRENT_LIST_DIR}/../../Headers/SDL_image.h" _sdl_image_h)
string(REGEX MATCH "#define[ \t]+SDL_IMAGE_MAJOR_VERSION[ \t]+([0-9]+)" _sdl_major_re "${_sdl_image_h}")
set(_sdl_major "${CMAKE_MATCH_1}")
string(REGEX MATCH "#define[ \t]+SDL_IMAGE_MINOR_VERSION[ \t]+([0-9]+)" _sdl_minor_re "${_sdl_image_h}")
set(_sdl_minor "${CMAKE_MATCH_1}")
string(REGEX MATCH "#define[ \t]+SDL_IMAGE_PATCHLEVEL[ \t]+([0-9]+)" _sdl_patch_re "${_sdl_image_h}")
set(_sdl_patch "${CMAKE_MATCH_1}")
if(_sdl_major_re AND _sdl_minor_re AND _sdl_patch_re)
set(PACKAGE_VERSION "${_sdl_major}.${_sdl_minor}.${_sdl_patch}")
else()
message(AUTHOR_WARNING "Could not extract version from SDL_image.h.")
return()
endif()
if(PACKAGE_FIND_VERSION_RANGE)
# Package version must be in the requested version range
if ((PACKAGE_FIND_VERSION_RANGE_MIN STREQUAL "INCLUDE" AND PACKAGE_VERSION VERSION_LESS PACKAGE_FIND_VERSION_MIN)
OR ((PACKAGE_FIND_VERSION_RANGE_MAX STREQUAL "INCLUDE" AND PACKAGE_VERSION VERSION_GREATER PACKAGE_FIND_VERSION_MAX)
OR (PACKAGE_FIND_VERSION_RANGE_MAX STREQUAL "EXCLUDE" AND PACKAGE_VERSION VERSION_GREATER_EQUAL PACKAGE_FIND_VERSION_MAX)))
set(PACKAGE_VERSION_COMPATIBLE FALSE)
else()
set(PACKAGE_VERSION_COMPATIBLE TRUE)
endif()
else()
if(PACKAGE_VERSION VERSION_LESS PACKAGE_FIND_VERSION)
set(PACKAGE_VERSION_COMPATIBLE FALSE)
else()
set(PACKAGE_VERSION_COMPATIBLE TRUE)
if(PACKAGE_FIND_VERSION STREQUAL PACKAGE_VERSION)
set(PACKAGE_VERSION_EXACT TRUE)
endif()
endif()
endif()
# if the using project doesn't have CMAKE_SIZEOF_VOID_P set, fail.
if("${CMAKE_SIZEOF_VOID_P}" STREQUAL "")
set(PACKAGE_VERSION_UNSUITABLE TRUE)
endif()

61
Library/SDL2_image-2.5.2/Xcode/pkg-support/resources/CMake/sdl2_image-config.cmake Normal file
View File

@@ -0,0 +1,61 @@
# SDL2_image CMake configuration file:
# This file is meant to be placed in Resources/CMake of a SDL2_image framework
# INTERFACE_LINK_OPTIONS needs CMake 3.12
cmake_minimum_required(VERSION 3.12)
include(FeatureSummary)
set_package_properties(SDL2_image PROPERTIES
URL "https://www.libsdl.org/projects/SDL_image/"
DESCRIPTION "SDL_image is an image file loading library"
)
set(SDL2_image_FOUND TRUE)
set(SDL2IMAGE_AVIF FALSE)
set(SDL2IMAGE_BMP TRUE)
set(SDL2IMAGE_GIF TRUE)
set(SDL2IMAGE_JPG TRUE)
set(SDL2IMAGE_JXL FALSE)
set(SDL2IMAGE_LBM TRUE)
set(SDL2IMAGE_PCX TRUE)
set(SDL2IMAGE_PNG TRUE)
set(SDL2IMAGE_PNM TRUE)
set(SDL2IMAGE_QOI TRUE)
set(SDL2IMAGE_SVG TRUE)
set(SDL2IMAGE_TGA TRUE)
set(SDL2IMAGE_TIF TRUE)
set(SDL2IMAGE_XCF TRUE)
set(SDL2IMAGE_XPM TRUE)
set(SDL2IMAGE_XV TRUE)
set(SDL2IMAGE_WEBP FALSE)
set(SDL2IMAGE_JPG_SAVE FALSE)
set(SDL2IMAGE_PNG_SAVE FALSE)
set(SDL2IMAGE_VENDORED FALSE)
set(SDL2IMAGE_BACKEND_IMAGEIO FALSE)
set(SDL2IMAGE_BACKEND_STB TRUE)
set(SDL2IMAGE_BACKEND_WIC FALSE)
string(REGEX REPLACE "SDL2_image\\.framework.*" "SDL2_image.framework" _sdl2image_framework_path "${CMAKE_CURRENT_LIST_DIR}")
string(REGEX REPLACE "SDL2_image\\.framework.*" "" _sdl2image_framework_parent_path "${CMAKE_CURRENT_LIST_DIR}")
f
# All targets are created, even when some might not be requested though COMPONENTS.
# This is done for compatibility with CMake generated SDL2_image-target.cmake files.
if(NOT TARGET SDL2_image::SDL2_image)
add_library(SDL2_image::SDL2_image INTERFACE IMPORTED)
set_target_properties(SDL2_image::SDL2_image
PROPERTIES
INTERFACE_COMPILE_OPTIONS "-F;${_sdl2image_framework_parent_path}"
INTERFACE_INCLUDE_DIRECTORIES "${_sdl2image_framework_path}/Headers"
INTERFACE_LINK_OPTIONS "-F;${_sdl2image_framework_parent_path};-framework;SDL2_image"
COMPATIBLE_INTERFACE_BOOL "SDL2_SHARED"
INTERFACE_SDL2_SHARED "ON"
)
endif()
unset(_sdl2image_framework_path)
unset(_sdl2image_framework_parent_path)